controls/templates/AbstractListItem.qml

/*
 *   Copyright 2010 Marco Martin <notmart@gmail.com>
 *
 *   This program is free software; you can redistribute it and/or modify
 *   it under the terms of the GNU Library General Public License as
 *   published by the Free Software Foundation; either version 2, or
 *   (at your option) any later version.
 *
 *   This program is distributed in the hope that it will be useful,
 *   but WITHOUT ANY WARRANTY; without even the implied warranty of
 *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *   GNU Library General Public License for more details
 *
 *   You should have received a copy of the GNU Library General Public
 *   License along with this program; if not, write to the
 *   Free Software Foundation, Inc.,
 *   51 Franklin Street, Fifth Floor, Boston, MA  2.010-1301, USA.
 */

import QtQuick 2.1
import QtQuick.Layouts 1.0
import QtQuick.Controls 1.0 as Controls
import QtQuick.Controls.Private 1.0
import org.kde.kirigami 1.0

Item {
    id: listItem
    
     default property Item contentItem

    property alias supportsMouseEvents: itemMouse.enabled

    signal clicked


    signal pressAndHold

    property bool checked: false

    property alias pressed: itemMouse.pressed

    property alias containsMouse: itemMouse.containsMouse

    property bool sectionDelegate: false

    property bool separatorVisible: true

    property Item background

    property color textColor: Theme.viewTextColor

    property color backgroundColor: Theme.viewBackgroundColor

    property color activeTextColor: Theme.highlightedTextColor

    property color activeBackgroundColor: Theme.highlightColor

    implicitWidth: contentItem ? contentItem.childrenRect.width : 0

    implicitHeight: contentItem.height + Units.smallSpacing * 5

    width: parent ? parent.width : implicitWidth
    Layout.fillWidth: true

    opacity: enabled ? 1 : 0.6

    height: visible ? implicitHeight : 0

    onContentItemChanged: {
        contentItem.parent = paddingItem;
    }

    Component.onCompleted: {
        itemMouse.integrateBackground()
    }

    MouseArea {
        id: itemMouse
        anchors.fill: parent
        enabled: true
        hoverEnabled: !Settings.isMobile

        onClicked: listItem.clicked()
        onPressAndHold: listItem.pressAndHold()

        Item {
            id: paddingItem
            z: 2
            anchors {
                fill: parent
                margins: Units.smallSpacing
            }
        }

        function integrateBackground() {
            if (background) {
                background.parent = itemMouse;
                background.anchors.fill = itemMouse;
            }
        }
    }

    onBackgroundChanged: {
        itemMouse.integrateBackground()
    }

    Accessible.role: Accessible.ListItem
}