Page.qml

/*
 *   Copyright 2015 Marco Martin <mart@kde.org>
 *
 *   This program is free software; you can redistribute it and/or modify
 *   it under the terms of the GNU Library General Public License as
 *   published by the Free Software Foundation; either version 2, or
 *   (at your option) any later version.
 *
 *   This program is distributed in the hope that it will be useful,
 *   but WITHOUT ANY WARRANTY; without even the implied warranty of
 *   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *   GNU Library General Public License for more details
 *
 *   You should have received a copy of the GNU Library General Public
 *   License along with this program; if not, write to the
 *   Free Software Foundation, Inc.,
 *   51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
 */

import QtQuick 2.1
import QtQuick.Layouts 1.2
import org.kde.kirigami 1.0
import "private"

Item {
    id: root

    property string title

    property int leftPadding: Units.gridUnit

    property int topPadding: Units.gridUnit

    property int rightPadding: Units.gridUnit

    property int bottomPadding: Units.gridUnit

    default property alias contentData: container.data

    property Flickable flickable

    //TODO: remove
    property alias contextualActions: actionsGroup.contextualActions

    //TODO: remove
    property alias mainAction: actionsGroup.main

    //TODO: remove
    property alias leftAction: actionsGroup.left

    //TODO: remove
    property alias rightAction: actionsGroup.right

    readonly property alias actions: actionsGroup

    PageActionPropertyGroup {
        id: actionsGroup
    }

    property Item background

    onBackgroundChanged: {
        background.z = -1;
        background.parent = root;
        background.anchors.fill = root;
    }

    signal backRequested(var event);

    Item {
        id: container
        onChildrenChanged: {
            //NOTE: make sure OverlaySheets are directly under the root
            //so they are over all the contents and don't have margins
            //TODO: OverlayDrawers as well?
            //search for an OverlaySheet, unfortunately have to blind test properties
            //as there is no way to get the classname from qml objects
            for (var i = children.length -1; i >= 0; --i) {
                var child = children[i];
                if (child.toString().indexOf("OverlaySheet") === 0) {
                    child.parent = root;
                }
            }
        }
        anchors {
            fill: parent
            leftMargin: leftPadding
            topMargin: topPadding + (applicationWindow === undefined || applicationWindow().wideScreen ? 0 : applicationWindow().header.height)
            rightMargin: rightPadding
            bottomMargin: bottomPadding
        }
    }

    Loader {
        z: 9999
        parent: root
        anchors {
            left: parent.left
            right: parent.right
            bottom: parent.bottom
        }
        height: item ? item.height : 0
        source: applicationWindow().header && applicationWindow().header.toString().indexOf("ToolBarApplicationHeader") !== 0 ? Qt.resolvedUrl("./private/ActionButton.qml") : ""
    }

    Layout.fillWidth: true
}